Announcement

**Mike Doty** · 28 Feb 2009, 01:07 AM

'This might help

Code:

#COMPILE EXE
#DIM ALL
#BREAK ON
FUNCTION PBMAIN () AS LONG
  LOCAL iErrCode AS LONG, E AS LONG
  E= 0   'no error
  E = 1  'error
DO
   'iErrCode    = 0           'this variable placed here gives expected results.
   ? "TOP LOOP"
   SLEEP 500
  DO
    ? "SIMULATE INPUT"
    SLEEP 500
    'input file
    IF E THEN
      ? "3 ERROR"                    'Here's the problem block..
      SLEEP 500
      iErrCode = E
      E = 0
      iErrCode = 0
      ITERATE LOOP                     'Iterate loop is never executed. Falls through.
      ? "3.5 FALL THROUGH"
     END IF
    'output file
    
     IF E THEN
      ? "4 ERROR";
      SLEEP 500
      iErrCode = E
      'CALL ErrTrap(iErrCode)
      E= 0  'ERRCLEAR
      iErrCode = 0
      'CLOSE #hOutFile
      'KILL sOutFileName                 'might want an ERRCLEAR after this
      ITERATE LOOP
      END IF
  LOOP
  ? "You got here
  SLEEP 500
LOOP WHILE iErrCode <> 0       'we shouldn't get here if the IF ERR block is executed.
END FUNCTION

**Michael K. Dealey** · 28 Feb 2009, 12:14 PM

Mike,

I appreciate you looking at this but I don't understand what you've done.
In your example above you have explicitly assigned a value to 'E' (and it's always initialized to TRUE) rather than trapping an error with the ERR function. You've also moved the 'simulated' file handling code to the inside the second loop. I can't structure the actual program like that, otherwise (error or no error) the program will constantly be trying to open and close files while the screen handling is going on.

I've put together a much shorter, no-frills version that demonstrates the problem. I'm just trying to understand this behavior. There is nothing in the
documentation (as I understand it) to negate further execution of the statements in the IF block simply because the ERR value has been set to 0.
You almost need to watch this in the debugger to see that the ITERATE LOOP
statement is reached but ignored. It simply jumps out of the outer DO..WHILE loop.

Can anyone clarify this?

Code:

#COMPILE EXE
#DIM ALL
#BREAK ON

FUNCTION PBMAIN () AS LONG
  LOCAL iErrCode AS LONG, E AS LONG
  LOCAL hInpFile AS LONG, iColPos AS LONG
  LOCAL sInFileName AS STRING, sKey AS STRING
  
DO
 
   LOCATE 6, 38: ? "TOP LOOP"
   sInFileName = ""
   sKey        = ""
   iColPos     = 35
   
   LOCATE 12, 12 : PRINT "Enter a Bad File Name: "; "              "
   LOCATE 12, iColPos : PRINT "_"
   
   
   DO
       CURSOR OFF
       LOCATE 8, 35 : PRINT "INSIDE LOOP 2"
     
       sKey = WAITKEY$
   
       SELECT CASE LEN(sKey)
           CASE 1                                      'normal key
               IF sKey = $CR THEN
                  EXIT DO
               END IF
               LOCATE 12, iColPos
               PRINT sKey; "_" : INCR iColPos
               sInFileName = sInFileName & sKey
           CASE 2                                   'extended key
               IF sKey = CHR$(0, 45) THEN           'ALT + X
                  EXIT FUNCTION
               END IF
       END SELECT
   LOOP

   OPEN sInFileName FOR INPUT AS #hInpFile
   IF ERR THEN                                          'Here's the problem block..
      iErrCode = ERR
      LOCATE 15, 35
      ? "ERROR = " & STR$(iErrCode)
      SLEEP 500
      ERRCLEAR
      iErrCode = ERR                                     'iErrCode now = 0.
      LOCATE 16, 32 : ? "iErrCode = " & STR$(iErrCode)   'We get here,
      SLEEP 500
      ITERATE LOOP                                       'but never here.
   END IF                                                'is that normal/expected?
                                                         'On the other hand, if you comment out the second
                                                         'iErrCode = ERR, then the loop iterates as expected.
LOOP WHILE iErrCode <> 0

LOCATE 18, 33 : PRINT "how did I get here?"
WAITKEY$

END FUNCTION

**Mike Doty** · 28 Feb 2009, 12:23 PM

1) The inner loop is exited immediately after imput with EXIT DO.
2) When the ITERATE is executed, only the outer loop is active.

**Michael K. Dealey** · 28 Feb 2009, 01:20 PM

1) The inner loop is exited immediately after imput with EXIT DO.
2) When the ITERATE is executed, only the outer loop is active.

Yes, I see that. Exactly what I want. But it's not actually working that way.
If the user enters a non-existent file name, an error message is displayed and the outer loop should be repeated, allowing them to retry. But this only happens if the second iErrCode = 0 statement is left out of the error trap.

Why? Is ERRCLEAR preventing further execution of the statements in the IF block? Apparently not entirely, because the two lines after ERRCLEAR get executed. Why suddenly does ITERATE LOOP get ignored?

Comment that line out and run the program (line 52). You'll get the expected results (unless you actually supply a valid file name).

Sorry if I'm not seeing something obvious or am explaining this wrong.

Thanks.

**John Gleason** · 28 Feb 2009, 01:47 PM

It seems to be correct as I commented below:

Code:

   IF ERR THEN                                          'Here's the problem block..
      iErrCode = ERR
      LOCATE 15, 35
      ? "ERROR = " & STR$(iErrCode)
      SLEEP 500
      ERRCLEAR
      iErrCode = ERR                                     'iErrCode now = 0.
      LOCATE 16, 32 : ? "iErrCode = " & STR$(iErrCode)   'We get here,
      SLEEP 500                                          'I did get here stepping thru using debugger
      ITERATE LOOP                                       'and here it exits loop because iErrCode = 0 and it loops only if iErrCode <> 0
   END IF                                                'is that normal/expected? In my test it works as expected.
                                                         'On the other hand, if you comment out the second
                                                         'iErrCode = ERR, then the loop iterates as expected.
LOOP WHILE iErrCode <> 0

LOCATE 18, 33 : PRINT "how did I get here?"
WAITKEY$

**Mike Doty** · 28 Feb 2009, 02:10 PM

'Here is similar logic to hopefully help
'Added FREEFILE
'Used ERRCLEAR instead of ERR

Code:

#COMPILE EXE
#DIM ALL
#BREAK ON
FUNCTION PBMAIN () AS LONG
  LOCAL sInFileName AS STRING, hInpFile AS LONG, iErrCode AS LONG
  DO
    ? "Input file name ";
    LINE INPUT sInFileName
    IF LEN(sInFileName) = 0 THEN EXIT FUNCTION 'not exit do
 
    iErrCode = 0             'init each time
    hInpFile = FREEFILE      'added this
    OPEN sInFileName FOR INPUT AS #hInpFile
    IF ERR THEN
      iErrCode = ERRCLEAR
      ? "iErrCode" + STR$(iErrCode)
      REM ITERATE LOOP  'no longer needed
    END IF
  LOOP WHILE iErrCode
  ? "File found"
  SLEEP 2000
END FUNCTION

**Michael Mattias** · 28 Feb 2009, 02:35 PM

This might be one of the few times I would actually break out the stepping debugger.

Seems pretty clear the "flow" is not going where you think it is going. So flow with it and see where it *IS* going.

**Peter Jinks** · 28 Feb 2009, 03:17 PM

Hi Michael,

It seems to me that you may be under the impression that ITERATE LOOP jumps back to the start of the loop immediately. That is not the case. It causes execution to go to the end of the LOOP - where the condition will be evaluated again and the loop may repeat, or it may exit. In this case, you are setting

Code:

iErrCode = 0

and then your condition is

Code:

LOOP WHILE iErrCode <> 0

so, naturally, the LOOP exits.

From the Help file:

ITERATE is just like using a GOTO to the line immediately before the NEXT statement (of a FOR...NEXT loop), the LOOP statement (of a DO...LOOP loop), or the WEND statement (of a WHILE..WEND loop). For example, the following code fragments are equivalent:

Code:

FOR ix = 1 TO 100

  ...

  ITERATE FOR

  ...

NEXT

 

FOR ix = 1 TO 100

  ...

  GOTO iterateForLoop

  ...

iterateForLoop:

NEXT

Regards,

Pete.

**Michael K. Dealey** · 28 Feb 2009, 03:24 PM

when all else fails....RTFM

...yes, I'm a victim of the age-old adage.

This is not a case of not understanding the IF-END IF block or the scope of the
value of iErrCode. Nope, I have been assuming all along that ITERATE LOOP acted in the opposite manner than as documented.

And just as I'm typing this I notice that Peter is telling you what I was assuming.

I think I'll go outside and sit in the sun for a while.

Thank you guys for your time. Sorry to have been so stupid.

-Michael.

**Mike Doty** · 28 Feb 2009, 03:26 PM

Not asking questions is stupid. Glad it is fixed.

**Michael K. Dealey** · 28 Feb 2009, 03:33 PM

Originally posted by Michael Mattias View Post

This might be one of the few times I would actually break out the stepping debugger.

Seems pretty clear the "flow" is not going where you think it is going. So flow with it and see where it *IS* going.

Michael, this is exactly how I got this erroneous assumption in my head a long time ago.

You won't see this executed in the stepping debugger. If the error condition was met, the debugger will jump back to the beginning of the loop. You won't see it jump to the LOOP WHILE iErrCode <> 0 before returning to the top of the loop.

Like I said, should of RTFM.

Thanks everyone.

-Michael.

**Michael Mattias** · 1 Mar 2009, 09:29 AM

If the error condition was met, the debugger will jump back to the beginning of the loop. You won't see it jump to the LOOP WHILE iErrCode <> 0 before returning to the top of the loop

Hmm.... based on the doc, that's not where the stepping debugger should have gone in 'step mode' if you ask me. (No one did).

Seems to me the 'next statement' when ITERATE is executed shoud be the LOOP statement.

MCM

Announcement

IF.. END IF and an Unrelated Question

IF.. END IF and an Unrelated Question

Comment

Comment

Comment

Comment

Comment

Comment

Comment

Comment

Comment

Comment

Comment

Comment