Announcement

**José Roca** · 31 Oct 2007, 11:42 AM

Because of the change of the forum software, some posts have become converted to lower case. Therefore, the alias names of the functions are incorrect.

Code:

'**************************
'File Name:  ShowData.inc
'**************************

'**************************************************************************************************
'This is essentially the main include file for the application.  I find that in a major application
'containing many forms/dialogs there will be common functions that aren't specific to any particular
'form.  These routines can be kept in a main include file such as this.  Also, types, equates and
'global variables can go there too.  In this particular application I put in here several equates
'(the control ids for the buttons, list box and text box), and the type I use to pass the window
'procedure parameters to message handlers.  Here they are...
'**************************************************************************************************
%IDC_BUTTON_1               =  1201
%IDC_BUTTON_2               =  1202
%IDC_EDIT_BOX               =  1203
%IDC_LIST_BOX               =  1204
%IDC_LB_LOAD                =  1205

Type WndEventArgs
  hWnd                      As Dword
  wParam                    As Dword
  lParam                    As Dword
End Type

'**************************************************************************************************
'Also with this file I included the ODBC equates and function declarations I needed to make this app
'work in the absence of including the three main ODBC includes along with the includes at the top
'of ShowData.bas (the main program file).  For you see, by my including that ODBC function call to
'load the edit box with database driver information, I complicated things for myself considerably
'here.  I didn't want to force my readers into having to go to the internet (at www.Powerbasic.com)
'to download special files (the ODBC Includes) just to get this app to work, so I pulled four
'function declarations and eight equates out of the ODBC includes, and am including them right here
'in the source code of ShowData.inc.  Here they are...
'**************************************************************************************************

'ODBC equates and function declarations needed to make SQLDrivers() work.
%SQL_NULL_HANDLE             = 0&
%SQL_HANDLE_ENV              = 1
%SQL_ATTR_ODBC_VERSION       = 200
%SQL_OV_ODBC3                = 3???
%SQL_IS_INTEGER              = (-6)
%SQL_FETCH_NEXT              = 1
%SQL_NO_DATA                 = 100
%SQL_ERROR                   = -1

Declare Function SQLAllocHandle Lib "ODBC32.DLL" Alias "SQLAllocHandle" _
( _
  Byval HandleType          As Integer,_
  Byval InputHandle         As Dword,_
  Byref OutPutHandle        As Dword _
) As Integer

Declare Function SQLSetEnvAttr LIB "ODBC32.DLL" ALIAS "SQLSetEnvAttr" _
( _
  Byval EnvironmentHandle   As Dword,_
  Byval Attribute           As Long,_
  Byref Value               As Any,_
  Byval StringLength        As Long _
) As Integer

Declare Function SQLDrivers LIB "ODBC32.DLL" ALIAS "SQLDrivers" _
( _
  Byval henv                As Dword,_
  Byval fDirection          As Word,_
  Byref szDriverDesc        As Asciiz,_
  Byval cbDriverDescMax     As Integer,_
  Byref pcbDriverDesc       As Integer,_
  Byref szDriverAttributes  As Asciiz,_
  Byval cbDrvrAttrMax       As Integer,_
  Byref pcbDrvrAttr         As Integer _
) As Integer

Declare Function SQLFreeHandle LIB "ODBC32.DLL" ALIAS "SQLFreeHandle" _
( _
  Byval HandleType          As Integer,_
  Byval TheHandle           As Dword _
) As Integer


'*****************************************************************************************
'Function Name:  blnGetSQLDriverData(hEditBox As Dword) As Long
'Purpose:        Sets up ODBC Environment for Calls To SQLDrivers
'                and fills text box with driver names and driver
'                attribute-value pairs
'Return Value    %TRUE or %FALSE indicating success or failure
'Parameters      One parameter - handle to edit box to fill with
'                driver descriptions and driver attribute values
'******************************************************************************************
Function blnGetSQLDriverData(hEditBox As Dword) As Long
  Local iLen1 As Integer,iLen2 As Integer
  Local szDriverAttr As Asciiz*256
  Local szDriverDes As Asciiz*64
  Local ptrByte As Byte Ptr
  Local strArr() As String
  Local strText As String
  Local hEnvr As Dword
  Register i As Long

  If SQLAllocHandle(%SQL_HANDLE_ENV,%SQL_NULL_HANDLE,hEnvr)<>%SQL_ERROR Then
     Call SQLSetEnvAttr(hEnvr,%SQL_ATTR_ODBC_VERSION,Byval %SQL_OV_ODBC3,%SQL_IS_INTEGER)
     While SQLDrivers(hEnvr,%SQL_FETCH_NEXT,szDriverDes,64,iLen1,szDriverAttr,256,iLen2)<>%SQL_NO_DATA
       strText=strText & szDriverDes & Chr$(13,10) & Chr$(13,10)
       Decr iLen2
       ptrByte=VarPtr(szDriverAttr)  'Loop through szDriverAttr buffer one byte at a time for iLen2 bytes
       For i=0 To iLen2              'substituting commas ( Chr$(44) ) for null bytes.  iLen1 and iLen2
         If @ptrByte[i]=0 Then       'are output parameters in SQLDrivers() ODBC function call.  Then
            @ptrByte[i]=44           'PowerBASIC's Parse statement will parse driver attribute pairs into
         End If                      'string array for output.
       Next i
       @ptrByte[iLen2]=0             'The last byte at iLen2 was a null that got turned into a comma.
       ReDim strArr(ParseCount(szDriverAttr)-1)
       Parse szDriverAttr,strArr()
       For i=0 To UBound(strArr,1)
         strText=strText & strArr(i) & Chr$(13,10)
       Next i
       strText=strText & Chr$(13,10) & Chr$(13,10)
     Loop
     Call SQLFreeHandle(%SQL_HANDLE_ENV,hEnvr)
     Call SetWindowText(hEditBox,Byval StrPtr(strText))
     blnGetSQLDriverData=%TRUE
  Else
     blnGetSQLDriverData=%FALSE
  End If
End Function

**Larry Burford** · 31 Oct 2007, 11:54 AM

Thank you Jose. That was the problem.

**Knuth Konrad** · 1 Nov 2007, 05:07 AM

Larry,

when posting source code, especially larger pieces like you did, enclosing the code within [ code ][ /code ] (without the spaces), improves readability a lot, as the forum keeps proper formatting:

(Without code tags)

Type WndEventArgs
hWnd As Dword
wParam As Dword
lParam As Dword
End Type

(With code tags)

Code:

Type WndEventArgs
  hWnd                      As Dword
  wParam                    As Dword
  lParam                    As Dword
End Type

**Michael Mattias** · 1 Nov 2007, 08:11 AM

Code:

redim strarr(parsecount(szdriverattr)-1) 'parsecount returns a one based count, but parse
parse szdriverattr,strarr() 'starts storing parsed strings into element zero

Not directly on topic, but for those who are more comfortable with '1-based' arrays but don't want to give up the documented performance benefits of using zero-based arrays...

Code:

  N = NumberOfItems in array
  REDIM  theArray (n) 
  PARSE  bigString, theArray()     ' parse into elements 0:n-1
    ---   or ------
  LINE INPUT #h, TheArray()      ' load from disk into elements 0:n-1
  ARRAY INSERT theArray(0), ""   ' shift elements to 1:n

This makes element zero a null and moves all your 'records' to elements 1 to N

MCM

**Larry Burford** · 1 Nov 2007, 12:36 PM

[QUOTE=Knuth Konrad;267413]Larry,

when posting source code, especially larger pieces like you did, enclosing the code within [ code ][ /code ] (without the spaces), improves readability a lot, as the forum keeps proper formatting:

Looking back at my opening post, I see what you mean. And when I post code of my own (usually) I do use the tags.

But in this case I was quoting someone else. And that someone else had used the tags in THEIR post.
So, why did the quoting process remove the tags? I PROBABLY should have attempted to edit my post before I submitted it.

===
On the ohter hand, the message board software POSITIVELY should have handled this for me.
===

?No es?

**Larry Burford** · 1 Nov 2007, 01:08 PM

Michael,

Thanks for the tip.

I'm usually agnostic when it comes to zero based arrays versus the alternatives. But that is mostly because I've not yet found an application where it made a real difference in performeace.

One of these days, however, I'll find a strong need for better performance with a non-zero based array, and I will smile as I contemplate your contribution. (I might even send you another note.)

Announcement

Question about ShowData (in Fred's SDK tutorial )

Question about ShowData (in Fred's SDK tutorial )

Comment

Comment

Comment

Comment

Comment

Comment