Announcement

**Pierre Bellisle** · 10 Jan 2008, 12:25 PM

Cliff,
I modified the SP_DEVICE_INTERFACE_DETAIL_DATA type
and set DeviceInterfaceDetailData.cbSize to SIZEOF(SP_DEVICE_INTERFACE_DETAIL_DATA)
CbSize must be 5 for ansi or 6 for unicode, this is the original size of the structure.
I also created a big enought DeviceInterfaceDetailData buffer
and used pointers to access it.

Here it is... Have fun.

Code:

#COMPILE EXE '#Win 8.04#
#DIM ALL
#INCLUDE "Win32Api.inc" '#2005-01-27#
 
%DIGCF_DEFAULT         = &H00000001
%DIGCF_PRESENT         = &H00000002
%DIGCF_ALLCLASSES      = &H00000004
%DIGCF_PROFILE         = &H00000008
%DIGCF_DEVICEINTERFACE = &H00000010
 
TYPE SP_DEVICE_INTERFACE_DETAIL_DATA
 cbSize     AS DWORD
 DevicePath AS ASCIIZ * 1
END TYPE
 
TYPE SP_DEVICE_INTERFACE_DATA
 cbSize             AS DWORD
 InterfaceClassGuid AS GUID
 Flags              AS DWORD
 Reserved           AS DWORD
END TYPE
 
TYPE SP_DEVINFO_DATA
 cbSize    AS DWORD
 ClassGuid AS GUID
 DevInst   AS DWORD
 Reserved  AS DWORD
END TYPE
 
DECLARE FUNCTION HidD_GetHidGuid LIB "hid.dll" ALIAS "HidD_GetHidGuid"(_
 BYREF HidGuid AS GUID) AS LONG
 
DECLARE FUNCTION SetupDiGetDeviceInterfaceDetail LIB "SetupApi.DLL" ALIAS "SetupDiGetDeviceInterfaceDetailA"( _
 BYVAL hDeviceInfoSet                AS DWORD                          , _
 BYREF DeviceInterfaceData           AS SP_DEVICE_INTERFACE_DATA       , _
 BYREF DeviceInterfaceDetailData     AS SP_DEVICE_INTERFACE_DETAIL_DATA, _
 BYVAL DeviceInterfaceDetailDataSize AS DWORD                          , _
 BYREF RequiredSize                  AS DWORD                          , _
 BYREF DeviceInfoData                AS SP_DEVINFO_DATA) AS LONG
 
DECLARE FUNCTION SetupDiGetClassDevs LIB "SetupApi.DLL" ALIAS "SetupDiGetClassDevsA"( _
 BYREF ClassGuid  AS GUID, _
 BYREF Enumerator AS ASCIIZ, _
 BYVAL hwndParent AS DWORD, _
 BYVAL Flags      AS DWORD) AS DWORD
 
DECLARE FUNCTION SetupDiEnumDeviceInterfaces LIB "SETUPAPI.DLL" ALIAS "SetupDiEnumDeviceInterfaces"( _
 BYVAL DeviceInfoSet       AS DWORD, _
 BYREF DeviceInfoData      AS SP_DEVINFO_DATA, _
 BYREF InterfaceClassGuid  AS GUID, _
 BYVAL MemberIndex         AS DWORD, _
 BYREF DeviceInterfaceData AS SP_DEVICE_INTERFACE_DATA) AS LONG
'______________________________________________________________________________
 
FUNCTION PBMAIN () AS LONG
 LOCAL pDeviceInterfaceDetailData AS SP_DEVICE_INTERFACE_DETAIL_DATA POINTER
 LOCAL DeviceInterfaceData        AS SP_DEVICE_INTERFACE_DATA
 LOCAL zError                     AS ASCIIZ * 500
 LOCAL sDeviceInterfaceDetailData AS STRING
 LOCAL HidGuid                    AS GUID
 LOCAL hDeviceInfoSet             AS DWORD
 LOCAL BytesNeeded                AS DWORD
 LOCAL Retval                     AS LONG
 LOCAL LastError                  AS LONG
 LOCAL MemberIndex                AS LONG
 
 HidD_GetHidGuid(HidGuid) 'Get Class Guid, {4D1E55B2-F16F-11CF-88CB-001111000030} returned in HidGuid
 
 'Get handle to a device information set (Use %DIGCF_PRESENT in flags if wanting only connected devices)
 hDeviceInfoSet = SetupDiGetClassDevs(HidGuid, BYVAL %NULL, BYVAL %NULL, %DIGCF_DEVICEINTERFACE)       ' Get a handle to the device list...
 
 'Get Device Interface Data
 MemberIndex = 0 'Begin with 0 and increment until no more devices are detected.
 DO
   DeviceInterfaceData.cbSize = SIZEOF(DeviceInterfaceData) 'Set the structure size
   'Get DeviceInterfaces
   Retval = SetupDiEnumDeviceInterfaces(hDeviceInfoSet, BYVAL %NULL, HidGuid, MemberIndex, DeviceInterfaceData)
   LastError = GetLastError
   IF LastError = %ERROR_NO_MORE_ITEMS THEN
     MSGBOX "Done...",, "ERROR_NO_MORE_ITEMS"
   END IF
   IF Retval = %FALSE THEN
     EXIT DO 'Function returns FASLSE if error
   END IF
 
   'Get Interface Details, first call to get BytesNeeded
   Retval = SetupDiGetDeviceInterfaceDetail(hDeviceInfoSet, DeviceInterfaceData, _
                                            BYVAL %NULL, BYVAL %NULL, BytesNeeded, BYVAL %NULL)
 
   sDeviceInterfaceDetailData = NUL$(BytesNeeded) 'Create a big enought buffer
   pDeviceInterfaceDetailData = STRPTR(sDeviceInterfaceDetailData) 'Use a pointer to access data
   'CbSize must be 5 for ansi or 6 for unicode, this is the original size of the structure
   @pDeviceInterfaceDetailData.cbSize = SIZEOF(SP_DEVICE_INTERFACE_DETAIL_DATA)
   Retval = SetupDiGetDeviceInterfaceDetail(hDeviceInfoSet, DeviceInterfaceData, _
                                            BYVAL pDeviceInterfaceDetailData, _
                                            LEN(sDeviceInterfaceDetailData), _
                                            BytesNeeded, BYVAL %NULL)
   LastError = GetLastError
 
   IF Retval THEN 'No error
     MSGBOX "MemberIndex" & STR$(MemberIndex) & $CRLF & _
            @pDeviceInterfaceDetailData.DevicePath & $CRLF & _
            "Len(DevicePath) " & STR$(LEN(@pDeviceInterfaceDetailData.DevicePath)) & $CRLF & _
            "BytesNeeded " & STR$(BytesNeeded),, "DevicePath" & STR$(MemberIndex)
   ELSE 'Error
     FormatMessage %FORMAT_MESSAGE_FROM_SYSTEM, BYVAL %NULL, LastError, %NULL, zError, SIZEOF(zError), BYVAL %NULL
     'ERROR_INVALID_USER_BUFFER = 1784
     MSGBOX zError & STR$(LastError),, "SetupDiGetDeviceInterfaceDetail"
     MSGBOX "BytesNeeded" & STR$(BytesNeeded),, "SetupDiGetDeviceInterfaceDetail"
     EXIT DO
   END IF
 
   INCR MemberIndex
 LOOP
 
END FUNCTION
'______________________________________________________________________________

**Cliff Nichols** · 10 Jan 2008, 04:51 PM

Thank you soooooooo muuuuuuuuch Pierre

After the loss of many nights and a few weekends reading, re-reading, and re-reading again, I just could not get this one concept down.

Thank you again, now I can put the :coffee2: down, and get back to my next hurdle.

I thought HidGuid was a class guid, but I may be wrong, I have to go back and look, but at least now I can go back and learn more without being stuck where I was.

Thank you, you are a life saver! (Maybe now I can get out and see my nieces and nephew, before they forget they have an uncle

)

**Mike Trader** · 10 Jan 2008, 05:09 PM

Cliff,
Thank you for tackling this one. This is on my list for this year to support some USB devices like GPS's directly. Please keep going :lam:

**Pierre Bellisle** · 10 Jan 2008, 10:06 PM

Cliff,
Your code was pretty close to work.
What I like about you is you're not a quitter.
You know, lost nights and weekends are a pleasure for mazo-coders.

I think wou will succeed with your project.

Take care of your nieces and nephew.

**Cliff Nichols** · 15 Jan 2008, 05:55 PM

Back to the Hair Ripping

Well after a few well deserved days visiting, I am back to the basics of porting USB complete.

Again I am stuck at a point, (But I almost "Get It"). From reading and re-reading (and the semi-muddy explanation from M$) then if I understand correctly the following holds true.

Device Class Guid <> Device Interface Guid (May in some cases be the same value though?)
I need the Device INTERFACE Guid to be able to get the device path

that said, then if it is a HID device then getting the HidGuid is easy with "HidD_GetHidGuid(HidGuid)", but what I do not know is if HidGuid is one that "DeviceClassGuid" just happens to equal "DeviceInterfaceGuid", or if the sub is asking the "DeviceInterfaceGuid" directly?

Now some information I can find directly because after extensive research, some "DeviceInterfaceGuid"s are defined in the WinIoCtl.inc or more particularly

Code:

' Device interface class GUIDs.
'
' need these GUIDs outside conditional includes so that user can
'   #include <winioctl.h> in precompiled header
'   #include <initguid.h> in a single source file
'   #include <winioctl.h> in that source file a second time to instantiate the GUIDs
'
#IF %DEF(%DEFINE_GUID)

$GUID_DEVINTERFACE_DISK                   = GUID$("{53F56307-B6BF-11D0-94F2-00A0C91EFB8B}"
$GUID_DEVINTERFACE_CDROM                  = GUID$("{53F56308-B6BF-11D0-94F2-00A0C91EFB8B}"
$GUID_DEVINTERFACE_PARTITION              = GUID$("{53F5630A-B6BF-11D0-94F2-00A0C91EFB8B}"
$GUID_DEVINTERFACE_TAPE                   = GUID$("{53F5630B-B6BF-11D0-94F2-00A0C91EFB8B}"
$GUID_DEVINTERFACE_WRITEONCEDISK          = GUID$("{53F5630C-B6BF-11D0-94F2-00A0C91EFB8B}"
$GUID_DEVINTERFACE_VOLUME                 = GUID$("{53F5630D-B6BF-11D0-94F2-00A0C91EFB8B}"
$GUID_DEVINTERFACE_MEDIUMCHANGER          = GUID$("{53F56310-B6BF-11D0-94F2-00A0C91EFB8B}"
$GUID_DEVINTERFACE_FLOPPY                 = GUID$("{53F56311-B6BF-11D0-94F2-00A0C91EFB8B}"
$GUID_DEVINTERFACE_CDCHANGER              = GUID$("{53F56312-B6BF-11D0-94F2-00A0C91EFB8B}"
$GUID_DEVINTERFACE_STORAGEPORT            = GUID$("{2ACCFE60-C130-11D2-B082-00A0C91EFB8B}"
$GUID_DEVINTERFACE_COMPORT                = GUID$("{86E0D1E0-8089-11D0-9CE4-08003E301F73}"
$GUID_DEVINTERFACE_SERENUM_BUS_ENUMERATOR = GUID$("{4D36E978-E325-11CE-BFC1-08002BE10318}"

which leads me to think there is at least a "PARTIAL" list of DeviceInterfaceGuid's out there, but unable to find most I am interested in, (nor the HidGuid, but then of course I could always use "HidD_GetHidGuid(HidGuid)" in this case), but I would like to cover as many bases as I can.

I did try the following (which helps a lot if I do not know the GUID I am after, but I do know the type of device I am after)

Code:

'*** Works but not for just USB
LOCAL zClassName AS ASCIIZ * %MAX_PATH
'zClassName = "USB"
zClassName = "ports"
'zClassName = "Unknown"
'zClassName = "printer"
'zClassName = "hidclass"
'zClassName = "USB\ROOT_HUB&"
Retval = SetupDiClassGuidsFromName(zClassName, BYVAL 0, BYVAL 0, BytesNeeded)
Retval = SetupDiClassGuidsFromName(zClassName, HidGuid, SIZEOF(HidGuid) * BytesNeeded, BytesNeeded)
MSGBOX GUIDTXT$(HidGuid)
     lResult = GetLastError()
     FormatMessage %FORMAT_MESSAGE_FROM_SYSTEM, BYVAL %NULL, lResult, %NULL, ErrorBuff, SIZEOF(ErrorBuff), BYVAL %NULL
MSGBOX errorBuff

Which gave me the same sort of info as trying to use the ClassGuid directly (leading me to think that the ones that work either have ClassGuid = InterfaceGuid, or maybe the Guid has a different interface somehow?)

I am almost ready to post what I have (since most of it suits my core purpose), but the stickler that I am, I wondered if I could (or should) take it one step further? and make it as "Generic" as I can? (Since almost ANY example I can find goes directly to HID-Only devices)

So my question...anyone with a list of "Interface" class guids? or anyone know how to get a "Interface" class guid? when all you have is the "DeviceClass" Guid to work from?

(Confusing I know...but now you know Y I am in the state I am in

)

**Cliff Nichols** · 24 Jan 2008, 06:36 PM

USB "In"-Complete

I just posted a working example so that others do not get as tripped up as I did so far.

My current plan of attack is to enum DeviceClassGuids, to get a list and then Enum InterfaceClassGuids to get another list, and then compare the VID and PID to put the 2 pieces together.

The only problem is, I do not know where precisely each piece of info is coming from? (probably registry, but not sure if "CurrentControlSet" or a combination of all the control sets? or where?) Not to mention user permissions (currently my tests are me, and I am the admin, so obviously I have no real problems so far...but that does not mean the general user won't have problems)

Attacking the problem from 2 sides takes like twice as long (but only noticeable on slower machines) so this may not be an issue, but what I would like to do is the following

Get the Device "Install" class guids and its information
Get the Device "Interface" class guids (preferably based from if I did not know that information previously)

I could probably do this by using the registry (depending which is the CORRECT one to use

I love a good puzzle (and this seems to be one), but sometimes one simple piece of information can make you wanna

until it is alive again, or flat out

Although it does get daunting at times, but whats a good challenge without a pitfall or 2?

**Pierre Bellisle** · 25 Jan 2008, 09:02 AM

Cliff,
the SetupApiClassInfo.INC file is absent from your post.
Maybe you could add it or give a link.

**Cliff Nichols** · 25 Jan 2008, 09:59 AM

Thanx Pierre,
SetupApiClassWrapper.INC was supposed to be marked SetupApiClassInfo.INC
I went back and corrected the post in the source code forum.

**Ian Cairns** · 25 Jan 2008, 01:54 PM

Thanks for doing the work on this. It will help to teach a lot of us to understand some more of such a complex subject.

Regards, Ian

**José Roca** · 25 Jan 2008, 02:19 PM

#IF %DEF(%DEFINE_GUID)

The C header uses this conditional equate because it uses the DEFINE_GUID macro to define the guids in WinIoCtl.h, but it makes no sense to use it in a PB header in which you are defining the guids using the built-in GUID$ function.

**Cliff Nichols** · 25 Jan 2008, 07:02 PM

>>> Ian
Thank you, I hope it does help others, and that others post what they have in similar (or different) aspects of how to grasp a basic learning of how USB works.

>>> José
I saw that too, but did know really understand the GUID concept (I have the basics of it's supposed to be a non-repeatable value, but my 1st intros to the concept were all VB6 OCX's so you can see why I do not like them)

>>> All
Any help with ideas? I greatly appreciate it.

At current any info seems to be you have to be part of the "Good Ole Boys" club and be a DDK developer

(Either that or they feel..."Unless you already know", (you wouldn't have to ask if you did), then the answer is "just do it our way and it will work" sort of attitude)
I could use PB's Example for Serial Ports...but that would be contradictory because absolutely NO ONE in PB has had the attitude of "If you don't know...I can't tell you"
Because this just is NOT the case, and even Bob has helped in areas that I was stuck on that went beyond the typical 90% use the example and it just works.

That is one thing I love about PB, everyone is willing to share their "lil nugget of knowledge, in their expertise" to let others learn

Anyways, I am still looking at the concept of being able to get the InterfaceClassGuid from the enumeration (somehow "DeviceAttach" does it if you attach a new device, but not sure how if I am just listing devices after they are attached) so currently I take my hard-coding (something I wish I could get away from) and enumerate those values and then compare the 2

bad part is...I do not truly know if enumeration is listing through registry keys? (and which ones if it is), or asking all devices to return a value?

**Raul Ortega** · 2 Oct 2009, 08:33 PM

I could not find: FileFolderFunctions.INC

I Cliff:

Thak's a lot for your aid.

When I downloaded the files in:

404 - File or directory not found.

http://www.powerbasic.com/support/pb...525#post307525

I Could not find:
FileFolderFunctions.INC

By
Raul Ortega

**Cliff Nichols** · 3 Oct 2009, 10:54 AM

Hi Raul,
Unfortunately the link you posted does not work for me, but I think I know which of my projects you may have been referring to.

If it was my "ListUsbSerialParallelDevice" then I think the below code is what is missing for "FileFolderFunctions.inc"

Code:

#IF NOT %DEF(%FILEFOLDERFUNCTIONS)
    %FILEFOLDERFUNCTIONS = 1
    DECLARE FUNCTION FileExist(FileSpec AS STRING, FileName AS STRING) AS LONG

    FUNCTION FileExist(FileSpec AS STRING, FileName AS STRING) EXPORT AS LONG
'*** Special Thanks to Aleksandr Dobrev for this function
'*** Should be expanded on, but for my example, I only need the 1st file that matches. CCN 12-31-07
        LOCAL fd    AS WIN32_FIND_DATA
        LOCAL hFind AS DWORD
        IF LEN(FileSpec) THEN
            hFind = FindFirstFile(BYCOPY FileSpec, fd)
            IF hFind <> %INVALID_HANDLE_VALUE THEN
                FindClose hFind
                FileName = fd.cFileName
                FUNCTION = %TRUE
            ELSE
                FUNCTION = %FALSE
        END IF
        ELSE
            FUNCTION = %FALSE
        END IF
    END FUNCTION
#ENDIF          'FILEFOLDERFUNCTIONS

I am looking back at old projects today and thinking of ideas to update them, so let me know if you have other problems. (PS. I am working on correcting the "OVERRIDE" problem as well)

**Doug McDonald** · 2 Dec 2009, 04:42 PM

WinUSB

Cliff, just a quick question. Have you done anything with WinUSB? It a driver that comes with Vista and can be installed on XP. I can't use the HID.dll Since I have to send a Setup Packet. My device Is written too via a control message and writes via an interrupt pipe. I'm trying to convert the sample in USB Complete that uses the WinUSB driver but for me its not easy to port from VB.net to PB and I can't find any samples in VB6.

Just wondering if you had any experience with this.

Thank you
Doug

**Doug McDonald** · 3 Dec 2009, 06:29 PM

WinUSB

I got it all the WinUSB working with VB.net now I just need to port it to PBwin. The hardest part for me had nothing to do with .Net but getting the Winusb Driver installed with the co-installers. Since I'm not to good a .Net stuff porting it over may be a challenge. Its just my basic lack of understanding, oh well that's how I learn

Thanks
Doug

**Cliff Nichols** · 4 Dec 2009, 09:47 AM

Hi Doug,
I did not know WinUSB even existed. But as a part of my re-write (which I may get around to looking at this weekend) I was gearing up on what I wrote earlier and how to make it better.

I guess now I have to look into WinUSB as well.

If you can post what you have running, I can take a look at it and see if it will give me a jumpstart on how to do the same in PB without the .NET effect.

**Doug McDonald** · 4 Dec 2009, 04:50 PM

Cliff,

Thank you. As you know any .Net code is too large to post here along with all the support files. If you can email me at [email protected] I can ZIP up the project and send it to you. Its basically its a chopped and modified version of Winusb demo for VB.net VS8 from Jan Axelson's Lakeview Research (USB Complete) website. I cut out everything I didn't need.

I'll be happy to send it to you. It would be great to get it into PBwin. The WinUSB driver is really powerful and if you do any microcontroller firmware that is used as a USB device it would be a great foundation for any PC host apps to have it in PowerBasic.

Doug

**Dev Oberholzer** · 2 May 2010, 03:24 AM

Cliff, Doug

Thank you for the sterling work here on a very complex topic.

I write applications for PalmOS PDAs that combine with some of my desktop apps written in PBWin. The old legacy Palm devices used to hotsync successfully with Windows via USB, so I relied on the built-in Palm and Windows drivers to handle the sync comms. Now, with the the advent 64 bit Windows 7, all the Palm USB hotsync drivers fail, and both Palm and MS seemingly have washed their hands of the problem. This will leave many of my existing users up the creek without a paddle, when they eventually migrate to 64-bit Windows 7, which I fear will be sooner than later.

Possible solutions:

Wait until Palm or MS provide a new driver.
Search for 3rd party solutions
Create my own 64-bit compatible USB driver in PBWin or CC, using either WinUSB or variations of Cliff's code samples.

I'm keen to tackle the third option, as I enjoy a challenge that looks impossible at first. Given the amount of effort both of you have already invested in this area, I wish to contribute to this strong foundation. Is this worth pursuing?

Dev Oberholzer

**Russ Srole** · 3 May 2010, 12:13 AM

Dev,

This probably will not make you're day, but I have a TX and syncing with WinXp worked great. Now that I have Win7 (64bit) at home, the usb interface does not work (as you know). It's a real pain. I found a way to sync it using the wifi;

http://forums.palm.com/t5/Windows-HotSync/How-to-HotSync-a-TX-to-Vista64-via-Wifi/m-p/186612?jump=true

Sometimes it even works, but not always. I don't know what the problem is, as you can certainly write usb software to run on 64bit windows. Good luck.

Russ

Announcement

USB Complete Port to PB

USB Complete Port to PB

Comment

Comment

Comment

Comment

Comment

Comment

Comment

Comment

Comment

Comment

Comment

Comment

Comment

Comment

Comment

Comment

Comment

Comment

Comment