Announcement

**Stuart McLachlan** · 10 May 2020, 11:54 PM

An absolute WAG, but do you need to pass OBJPTR(ppNotify) ?

**Pierre Bellisle** · 11 May 2020, 12:48 AM

RegisterControlChangeNotify works pretty well on my side.
Here is my callback...

Code:

'_____________________________________________________________________________

CLASS AudioEndpointVolumeCallbackOnNotify AS COM

 INTERFACE IAudioEndpointVolumeCallback $IID_IAudioEndpointVolumeCallback

   INHERIT IUNKNOWN 'Interface inherits from

   METHOD OnNotify(BYREF pNotify AS AUDIO_VOLUME_NOTIFICATION_DATA) AS LONG

     IF VARPTR(pNotify) = %NULL THEN
       METHOD = %E_INVALIDARG
     ELSE
       IF (hDlg <> %NULL) AND (pNotify.guidEventContext <> guidWinMasterVolContext) THEN

         'Post notification to main dialog
         'PostMessage(hDlg, %WM_APP, %ToolbarWinMasterWinMasterMuteButton, pNotify.bMuted)
         'PostMessage(hDlg, %WM_APP, %TrackbarWinMasterVol, pNotify.fMasterVolume * %TrackbarWinMasterMax) '%TrackbarWinMasterMax = 100

       END IF
       METHOD = %S_OK
     END IF

   END METHOD

 END INTERFACE

END CLASS
'_____________________________________________________________________________
'

**Jim Fritts** · 11 May 2020, 08:47 AM

Hmm, Interesting Pierre! I was looking into producing a class but had not finished it yet. Thank you!
Thank you Stuart

**Jim Fritts** · 11 May 2020, 09:44 AM

Pierre,
Can you register for both Speakers Volume/Mute and Microphone Volume/Mute? Likely I should use 2 classes to do that referencing AUDIO_VOLUME_NOTIFICATION_DATA1 for Speakers Volume/Mute and AUDIO_VOLUME_NOTIFICATION_DATA2 for Microphone Volume/Mute.

If I get that far then making a third class for microphone boost should not be a problem. Is that what you would do?

**Pierre Bellisle** · 11 May 2020, 01:19 PM

I did a quick and dirty test registering speaker volume/mute
and mike volume/mute to the same callback and it was triggered by both.
As said quick and dirty, I only add a beep in the callback.

So all should go real fine with two or more classes.

**Jim Fritts** · 11 May 2020, 02:22 PM

Ok Thanks

This is the Class version I have:

Code:

' ########################################################################################
' Class CIAudioEndpointVolumeCallback
' Interface name = _IAudioEndpointVolumeCallback
' IID = {657804FA-D6AD-4496-8A60-352752AF4F89}
' Inherited interface = IUnknown
' ########################################################################################

CLASS CIAudioEndpointVolumeCallback AS COM

 INTERFACE IAudioEndpointVolumeCallback $IID_IAudioEndpointVolumeCallback

  INHERIT IUNKNOWN

   ' =====================================================================================
   METHOD OnNotify ( _                                    ' VTable offset = 12
     BYREF pNotify AS AUDIO_VOLUME_NOTIFICATION_DATA _  ' __in PAUDIO_VOLUME_NOTIFICATION_DATA pNotify
   ) AS LONG                                            ' HRESULT

     'Method-Callback  that receives a pointer to the sample buffer.
     'Callback method for endpoint-volume-change notifications.
     'LOCAL TrackBarPos AS LONG

         WINBEEP(7000, 75)
     IF VARPTR(pNotify) = %NULL THEN
       METHOD = %E_INVALIDARG
     ELSE
       IF (hDlg <> %NULL) AND (pNotify.guidEventContext <> g_guid_1_Context) THEN

         'Post notification to main dialog
         PostMessageA (hDlg, %WM_APP, %CheckboxVolOnOffSpeaker, pNotify.bMuted)
         PostMessageA (hDlg, %WM_APP, %TrackbarVolSpeaker, pNotify.fMasterVolume * %TrackbarMax) '%TrackbarWinMasterMax = 100

       END IF
       METHOD = %S_OK
     END IF
   END METHOD
   ' =====================================================================================

 END INTERFACE

END CLASS

This is how I'm calling it.

Code:

FUNCTION SetVolumeCallback AS LONG
    'Pointer to the IAudioEndpointVolumeCallback interface that the client
    'is registering for notification callbacks. If the
    'RegisterControlChangeNotify method succeeds, it calls the AddRef
    'method on the client's IAudioEndpointVolumeCallback interface.

    LOCAL xhr   AS LONG

    IF ISOBJECT(gpIAudioEndpointVolumeStereoSpeakers) THEN

        xhr = CoCreateGuid (g_guid_1_Context)

        LET ppNotify = CLASS "CIAudioEndpointVolumeCallback"

        xhr = gpIAudioEndpointVolumeStereoSpeakers.RegisterControlChangeNotify(BYVAL ppNotify) 'IAudioEndpointVolumeCallback
        IF ISOBJECT(ppNotify) THEN
            ? "RegisterControlChangeNotify"
        END IF

        IF FAILED(xhr) THEN
            ? "Unable to set stereo speaker callback."
            FUNCTION = 0
            EXIT FUNCTION
        ELSE
            '? "Default stereo speaker callback."
        END IF

    END IF
    FUNCTION = 1
END FUNCTION

Initial test show it is working. Thank Heavens.

**Jim Fritts** · 12 May 2020, 09:16 AM

These work exceedingly well:
The first for speakers.
The second for microphone.
Now I just have to do a third for microphone Boost.
All with the same AUDIO_VOLUME_NOTIFICATION_DATA.
Very cool!

Code:

' ########################################################################################
' Class CIAudioEndpointVolumeCallback
' Interface name = _IAudioEndpointVolumeCallback
' IID = {657804FA-D6AD-4496-8A60-352752AF4F89}
' Inherited interface = IUnknown
' ########################################################################################

CLASS CIAudioEndpointVolumeCallback_1 AS COM

 INTERFACE IAudioEndpointVolumeCallback $IID_IAudioEndpointVolumeCallback

  INHERIT IUNKNOWN

   ' =====================================================================================
   METHOD OnNotify ( _                                      ' VTable offset = 12
     BYREF pNotify_1 AS AUDIO_VOLUME_NOTIFICATION_DATA _    ' __in PAUDIO_VOLUME_NOTIFICATION_DATA pNotify
   ) AS LONG                                            ' HRESULT

     'Method-Callback  that receives a pointer to the sample buffer.
     'Callback method for endpoint-volume-change notifications.

     IF VARPTR(pNotify_1) = %NULL THEN
       METHOD = %E_INVALIDARG
     ELSE
       IF (hDlg <> %NULL) THEN
           IF (pNotify_1.guidEventContext <> g_guid_1_Context) THEN
             PostMessageA (hDlg, %WM_APP, %CheckboxVolOnOffSpeaker, pNotify_1.bMuted)
             PostMessageA (hDlg, %WM_APP, %TrackbarVolSpeaker, pNotify_1.fMasterVolume * %TrackbarMax)
           END IF
       END IF

       METHOD = %S_OK
     END IF
   END METHOD
   ' =====================================================================================

 END INTERFACE

END CLASS

' ########################################################################################
' Class CIAudioEndpointVolumeCallback
' Interface name = _IAudioEndpointVolumeCallback
' IID = {657804FA-D6AD-4496-8A60-352752AF4F89}
' Inherited interface = IUnknown
' ########################################################################################

CLASS CIAudioEndpointVolumeCallback_2 AS COM

 INTERFACE IAudioEndpointVolumeCallback $IID_IAudioEndpointVolumeCallback

  INHERIT IUNKNOWN

   ' =====================================================================================
   METHOD OnNotify ( _                                      ' VTable offset = 12
     BYREF pNotify_2 AS AUDIO_VOLUME_NOTIFICATION_DATA _    ' __in PAUDIO_VOLUME_NOTIFICATION_DATA pNotify
   ) AS LONG                                            ' HRESULT

     'Method-Callback  that receives a pointer to the sample buffer.
     'Callback method for endpoint-volume-change notifications.

     IF VARPTR(pNotify_2) = %NULL THEN
       METHOD = %E_INVALIDARG
     ELSE
       IF (hDlg <> %NULL) THEN
           IF (pNotify_2.guidEventContext <> g_guid_2_Context) THEN
             'Post notification to main dialog
             PostMessageA (hDlg, %WM_APP, %CheckboxVolOnOffMicro, pNotify_2.bMuted)
             PostMessageA (hDlg, %WM_APP, %TrackbarVolMicro, pNotify_2.fMasterVolume * %TrackbarMax)
           END IF
       END IF

       METHOD = %S_OK
     END IF
   END METHOD
   ' =====================================================================================

 END INTERFACE

END CLASS

**Pierre Bellisle** · 12 May 2020, 02:31 PM

Looking at the code again, I removed some old experiment residue from it.
Added more infos on how to treat sub channels if needed...

Code:

'_____________________________________________________________________________

CLASS AudioEndpointVolumeCallbackOnNotify AS COM

 INTERFACE IAudioEndpointVolumeCallback $IID_IAudioEndpointVolumeCallback

   INHERIT IUNKNOWN 'Interface inherits from

   METHOD OnNotify(NotificationData AS AUDIO_VOLUME_NOTIFICATION_DATA) AS LONG

     PostMessage(hDlg, %WM_APP, %ButtonMute,  NotificationData.bMuted)
     PostMessage(hDlg, %WM_APP, %TrackbarVol, NotificationData.fMasterVolume * 100)
     METHOD = %S_OK

     'OutputDebugString("guidEventContext "        & GUIDTXT$(NotificationData.guidEventContext))
     'OutputDebugString("guidWinMasterVolContext " & GUIDTXT$(guidWinMasterVolContext))
     'OutputDebugString("Muted "          & FORMAT$(NotificationData.bMuted))
     'OutputDebugString("MasterVolume "   & FORMAT$(NotificationData.fMasterVolume, "0.000"))
     'OutputDebugString("Channels count " & FORMAT$(NotificationData.nChannels))
     'LOCAL index          AS LONG
     'LOCAL pChannelVolume AS SINGLE POINTER
     'pChannelVolume = VARPTR(NotificationData.afChannelVolumes(0))
     'FOR index = 0 TO NotificationData.nChannels - 1
     '  OutputDebugString(FORMAT$(index) & ") Volume " & FORMAT$(@pChannelVolume[index], "0.000"))
     'NEXT

   END METHOD

 END INTERFACE

END CLASS
'_____________________________________________________________________________
'

**Jim Fritts** · 12 May 2020, 03:23 PM

Nice, I'm not there yet. Speakers Volume plus Mute/Unmute are good. Microphone Volume plus Mute/Unmute are good.
Where I'm having a problem is the Microphone Boost.

Hmm I think I figured it out.

from IPart there is this:

Code:

   METHOD RegisterControlChangeCallback ( _             ' VTable offset = 56
     BYREF riid AS GUID _                               ' __in REFGUID riid
   , BYVAL pNotify AS IControlChangeNotify _            ' __in IControlChangeNotify *pNotify
   ) AS LONG                                            ' HRESULT

Looks like I'll have to create another class for that.

**Pierre Bellisle** · 12 May 2020, 03:54 PM

Jim, I guess you are referring to this thread of yours... Microphone with boost controls
After a quick test on my side under Windows 7, mute and vol works ok, the boost no.
Did you test on many machine?

**Jim Fritts** · 12 May 2020, 03:58 PM

Actually that post was a precursor to what I'm working on now. It had no callbacks. Currently I'm upgrading it. I only have WIN 10.

**Pierre Bellisle** · 12 May 2020, 04:13 PM

I found why boost did not work for me. The precursor code was not language independent.
You uses "Microphone Boost" and I got "Ampli microphone".

**Jim Fritts** · 12 May 2020, 04:25 PM

Yes, correct.

**Jim Fritts** · 13 May 2020, 11:50 AM

Still working on a callback for the Microphone Boost among other things. I implemented Speech Recognition so the microphone shows up solidly in the taskbar notification area. The speech recognition is just there to get the microphone hot. That is all. Recognition results are not interpreted.
All that is gained from this will be applied to the new VOX. VOX3. I figured it would be a pain.

This is something new to the recognition portion:

Code:

'_________________________________________________________________
'
' SUB RECOGNITION_ENABLE                 new 2020 MAY 13 new
'
' Includes workaround for recognition volume AGC forcing volume to 91
' The solution was to capture the volume level before using %SGDSActive
' and then reapplying the value after %SGDSActive was executed.
' For some unknown reason the callback didn't get a new level so the
' trackbar had to be refreshed as well.
'_________________________________________________________________

SUB RECOGNITION_ENABLE
  LOCAL LastValue AS SINGLE

  'NOTE: oMyGrammar.DictationSetState(%SGDSActive)           'Turn Dictation on.
  'This causes the microphone volume to move to 91 the second time it is enabled
  'instead of leaving the volume where it was originally set.
  'Microsoft's way of making speech recognition idiot proof.

  'Start the recognition by activating one of the grammars

  IF ISTRUE ISOBJECT(oRecoContext) THEN
      CALL GetVolumeMicrophone                   'workaround
      LastValue = giMasterMicrophoneLevel/100    'workaround

      IF giCCGrammarLoaded = 1 THEN
          IF gsBannerDictation = "*" THEN
              oMyGrammar.DictationSetState(%SGDSInactive)     'Turn Dictation off.
              oMyGrammar.CmdSetRuleIdState(0, %SGDSActive)    'turn command / contol on
          ELSE
              oMyGrammar.CmdSetRuleIdState(0, %SGDSInactive)  'turn command / contol off
              oMyGrammar.DictationSetState(%SGDSActive)       'Turn Dictation on.
          END IF
      ELSE
          oMyGrammar.DictationSetState(%SGDSActive)           'Turn Dictation on.
      END IF

      CALL SetVolumeMicrophone(LastValue)        'workaround
      CALL RefreshVolumeTrackbarPos(LastValue)   'workaround
  ELSE
      CALL PutEqualSignOnMarque
  END IF
END SUB

I'm loading Dictation grammar only but this change will also work with a Command and Control Grammar.

**Jim Fritts** · 13 May 2020, 10:49 PM

Yeah Haw success.
Here is the class:

Code:

' ########################################################################################
' Class CIControlChangeNotify
' Interface name = IControlChangeNotify
' IID = A09513ED-C709-4D21-BD7B-5F34C47F3947
' Inherited interface = IUnknown
' ########################################################################################

CLASS CIControlChangeNotify AS COM

 INTERFACE IControlChangeNotify $IID_IControlChangeNotify

    INHERIT IUNKNOWN

    ' =====================================================================================
    METHOD OnNotify ( _                                  ' VTable offset = 12
      BYVAL dwSenderProcessId AS DWORD _                 ' __in DWORD dwSenderProcessId
    , BYREF pguidEventContext AS GUID _                  ' __in LPCGUID pguidEventContext
    ) AS LONG                                            ' HRESULT
    ' =====================================================================================
       IF (hDlg <> %NULL) THEN
           IF (pguidEventContext <> g_guid_3_Context) THEN
             'Get the microphone boost values
             CALL GetVolumeMicrophoneBoost
           END IF
       END IF

       METHOD = %S_OK
     END METHOD

 END INTERFACE

END CLASS

Here is the way the Microphone Boost callback is set:

Code:

FUNCTION SetMicrophoneBoostCallback AS LONG

    LOCAL xhr   AS LONG

    IF ISOBJECT(pPartNext) THEN

        xhr = CoCreateGuid (g_guid_3_Context)

        LET ppNotify_3 = CLASS "CIControlChangeNotify"

        xhr = pPartNext.RegisterControlChangeCallback( _
                 IID_IAudioVolumeLevel, _
                 BYVAL ppNotify_3)

        IF FAILED(xhr) THEN
            ? "Unable to set microphone boost callback."
            FUNCTION = 0
            EXIT FUNCTION
        ELSE
            ? "Default microphone boost callback."
        END IF

    END IF
    FUNCTION = 1
END FUNCTION

**Pierre Bellisle** · 14 May 2020, 12:40 PM

This looks real good Jim!
Thanks for sharing.
Nice work... Microphone with boost controls v2

To my copy, I added...

Code:

[noparse]
CASE %ButtonSndRecord
  pid = SHELL("rundll32.exe shell32.dll,Control_RunDLL mmsys.cpl,,1")
[/noparse]

**Jim Fritts** · 14 May 2020, 02:04 PM

Thank you, Sir! It was a hard won battle.

Next will be the integration into VOX3 an SDK app and eventually into xBot.

**Pierre Bellisle** · 14 May 2020, 02:07 PM

I believe you about the hard won battle...
Good news is those are the ones that taste so much better...
Enjoy!

You deserve it!

**Pierre Bellisle** · 14 May 2020, 03:17 PM

Jim, those might be nice to add to avoid leaks...
IAudioEndpointVolume::unRegisterControlChangeNotify
IPart::unRegisterControlChangeCallback

Announcement

RegisterControlChangeNotify does not appear to work

RegisterControlChangeNotify does not appear to work

Comment

Comment

Comment

Comment

Comment

Comment

Comment

Comment

Comment

Comment

Comment

Comment

Comment

Comment

Comment

Comment

Comment

Comment

Comment