Anyone got a "Drag and Drop" example?

[David Clarke]

What are the basic concepts of dragging and dropping a file to a window or control?
I assume it causes some message to fire? With the file name and path?

[Gary Beene]

Hey Dave!

DragDrop Multiple Files

'Compilable Example:
#Compiler PBWin 9, PBWin 10
#Compile Exe
#Dim All
%Unicode=1
#Include "Win32API.inc"
Global hDlg As Dword

Function PBMain() As Long
   Dialog New Pixels, 0, "Drop Test",600,1400,200,200, %WS_OverlappedWindow To hDlg
   DragAcceptFiles hDlg, %True
   Control Add Label, hDlg, 200,"Drag/drop file anywhere within app!", 20,40,170,20
   Dialog Show Modal hDlg Call DlgProc
End Function

CallBack Function DlgProc() As Long
   Local i,FileCount As Long, FileName As WStringZ * %Max_Path, temp$
   Select Case Cb.Msg
      Case %WM_DROPFILES
         FileCount = DragQueryFile(Cb.WParam, -1, ByVal 0, 0)
         For i = 0 To FileCount-1
            DragQueryFile Cb.WParam, i, FileName, SizeOf(FileName)
            temp$ = temp$ + $CrLf + FileName
         Next i
         DragFinish Cb.WParam
         MsgBox "Dropped filenames: " + $CrLf + $CrLf + Trim$(temp$,$CrLf)
   End Select
End Function

[David Clarke]

Thanks Gary!
I figured it was something like that!

[John Montenigro]

This is a real DOH! moment... I was able compile Gary's code, and although I could see the icon in the button bar, I wasn't seeing the panel. And from Process Explorer, I could tell it was a running process and not hung... I thought this might be related to a glitch in a recent virus-scan, that maybe something essential had been affected. But other programs compiled and ran with no problem...

So after a good night's sleep, I noticed the x, y position in the DIALOG NEW statement, and realized the main panel was off my screen. Adjusted to 10,10 and of course, it was there and working properly...

DOH!, right?
-John

[Tim Lakinir]

Thanks John and Gary. The 10,10 did the job nicely

[Stuart McLachlan]

Just looked at his code. "600,1400" ?
Using a screen in portrait mode perhaps? That will be off the screen for a lot of people who cut paste the code to try it out

[Gary Beene]

Hey Stuart!

Yes, that code snippet was BEFORE Borje chastised me for not using code that centers the dialog on the screen! It did indeed fall off his screen.

In more recent snippets, I'm trying to do better. My 2560x1440 resolution spoils me.

[John Montenigro]

...Reminds me that I've wanted to incorporate "check user display" code in my programs that determines best x, y, xx, yy values before doing DIALOG NEW...
Last year I experimented with some code to respect the user's choice of taskbar height, so I just need to get in the habit of calling it first.

-John

[Gary Beene]

John, for all my released apps I use an INI file. When loading that file in WM_InitDialog, I set the dialog xy position centered on the screen. See my recent post on gbProcedures for the code example.

[John Montenigro]

Yup, I understand. I also use INI files to hold settings. However, in order to obtain those settings, I like when the program figures out the parameters of the screen/environment, and adjusts itself before displaying its main panel and writing the INI values.

-John

[Gary Beene]

John, the Settings function in gbProcedures does what you ask. Or, did I mis-understand your comment?

Here's the pertinent code ...

Sub Settings_INI(Task$)
   Local xResult, yResult, tempz, INIFileName As WStringZ * %Max_Path
   Local WinPla As WindowPlacement, x As Long
   Local DefaultX, DefaultY, wDeskTop, hDeskTop As Long

   'set ini filename
   INIFileName = Exe.Path$ + "gbprocedures.ini"
   If Task$ = "get" Then

      'get dialog width/height from INI file and use to set Dialog size
      GetPrivateProfileString "All", "Width", "1200", xResult, %Max_Path, INIFileName
      GetPrivateProfileString "All", "Height", "600", yResult, %Max_Path, INIFileName
      Dialog Set Size hDlg,Val(xResult), Val(yResult)   'width/height

      'default should be centered on screen
      Desktop Get Client To wDeskTop, hDeskTop
      DefaultX = (wDeskTop-Val(xResult))/2
      DefaultY = (hDeskTop-Val(yResult))/2

      'get dialog top/left from INI file and use to set Dialog location
      Getprivateprofilestring "All", "Left", Str$(DefaultX), xResult, %Max_Path, INIFileName
      Getprivateprofilestring "All", "Top", Str$(DefaultY), yResult,  %Max_Path, INIFileName
      Dialog Set Loc hDlg, Val(xResult), Val(yResult)   'left/top

[John Montenigro]

Well, it looks OK, but in a file where I was testing last year, I wrote a note that Desktop Get Client wasn't working properly. Might have had something to do with my using a taskbar that's 2 rows high? (yes, uncommon, but I like a 3-line clock display...) (Or maybe

I can't test your code or mine till tomorrow night, so I'm going to have to ponder awhile..

But a few questions come to mind - what if you don't want the first panel to be centered, but placed a certain distance from left and top edges? And what if the user has an unusual display (like 2 monitors?, or what if user has moved the taskbar to the left side?

Your code is great for most "normal" circumstances, but "what if" something is unusual, or your initial settings are fine for a double screen, but not for a single?

... more in the morning, I'm falling asleep on the keyboard! I've got to crash now...

-John

[Mike Doty]

Drop files into SQLite table
Thanks, Gary!

#DIM ALL
%Unicode=1
#INCLUDE ONCE "win32api.inc"
#INCLUDE ONCE "sqlitening.inc"

GLOBAL hDlg AS DWORD
FUNCTION SaveImage(sArray() AS STRING) AS LONG
 LOCAL x,hFile AS LONG, sBlob AS STRING
 slOpen "images.db3","C"
 slexe "create table if not exists t1(key integer primary key,data)"
 slexe "begin exclusive" 'lock database
 FOR x = LBOUND(sArray) TO UBOUND(sArray)
  hfile = FREEFILE  'Stuart got this, added
  OPEN sArray(x) FOR BINARY AS #hfile
  GET$ #hfile,LOF(hFile),sBlob
  CLOSE #hfile
  slexebind "insert into t1 values(null,?)",slBuildBindDat(sBlob)
 NEXT
 slexe "end"
 DIALOG SET TEXT hDlg,"Grand total dropped into Table " +_
                       slSelStr("select count(*) from t1")
END FUNCTION

FUNCTION PBMAIN() AS LONG
 DIALOG NEW PIXELS, 0, "Drop Test",,,400,200, %WS_OVERLAPPEDWINDOW TO hDlg
 DragAcceptFiles hDlg, 1 '%true
 CONTROL ADD LABEL, hDlg, 200,"Drag/drop file anywhere within app!", 20,40,170,20
 DIALOG SHOW MODAL hDlg CALL DlgProc
END FUNCTION

CALLBACK FUNCTION DlgProc() AS LONG
   LOCAL i,FileCount AS LONG, FileName AS WSTRINGZ * %MAX_PATH, temp$
   SELECT CASE CB.MSG
      CASE %WM_DROPFILES
         FileCount = DragQueryFile(CB.WPARAM, -1, BYVAL 0, 0)
         DIM sArray(FileCount-1) AS STRING
         FOR i = 0 TO FileCount-1
            DragQueryFile CB.WPARAM, i, FileName, SIZEOF(FileName)
            sArray(i) = FileName
         NEXT i
         DragFinish CB.WPARAM
         ? JOIN$(sArray(),$CR),,"Dropped filenames"
         SaveImage sArray()
   END SELECT
END FUNCTION

[Stuart McLachlan]

Drop files into SQLite table

Nice example.


But just to nit-pick
You are not assiging a value to hFile so you are opening the file AS 0
Help:
filenum& A unique integer value identifying the file, in the range 1 to 32767.

[Stuart McLachlan]

BTW, You don't need
DragAcceptFiles hDlg, 1 '%true
if you use
DIALOG NEW PIXELS, 0, "Drop Test",,,400,200, %WS_OVERLAPPEDWINDOW,,%WS_EX_ACCEPTFILES TO hDlg

[Mike Doty]

Good catches, updated code!!

[Stuart McLachlan]

A minor refinement. If you want to know where in the Window the files(s) are dropped
(allows you to do different things depending on where in the window they are dropped):

LOCAL p AS POINT
...
dragquerypoint CB.WPARAM,p
? "Dropped at Window pixel co-ordinates: " & STR$(p.x) & " ," & STR$(p.y),%MB_OK,"Files dropped"

[Michael Mattias]

Here's the pertinent code [To store dialog size and location in an INI file]

Another suggestion..

You could/should check the values retrieved to ensure they will be possible and/or visible and if not set some defaults.

Users have been known to edit INI files "because they can."