Announcement

**William Burns** · 15 Dec 2002, 07:35 PM

Here is an example of using the above SendKeys include file.

(It is also a simple example of using global hotkeys)

Code:

#COMPILE EXE      'Example program for SendKeys.Inc file
#REGISTER NONE
#DIM ALL
#INCLUDE "SendKeys.Inc" '<-- file found in Source Code forum (above)  - by William Burns
GLOBAL hDlg AS LONG
'=~=~=~=~=~=~=~=~=~=~=~=~=~=~=~=~=~=~=~=~=~=~=~=~=~=~=~=~=~=~=~=~=~=~=~
CALLBACK FUNCTION DlgProc
   STATIC nAtom() AS DWORD
   LOCAL sText    AS STRING
   LOCAL iRet     AS LONG
   LOCAL iCount   AS LONG
      SELECT CASE CBMSG
         CASE %WM_INITDIALOG
            iRet = TIMER
            REDIM nAtom(1:3)
            FOR iCount = 1 TO 3
               nAtom(iCount) = GlobalAddAtom ("My Hotkeys" + STR$(iRet + iCount))  'make each unique
               RegisterHotKey CBHNDL, nAtom(iCount), 2, 64 + iCount ' Ctrl-A-B-C
            NEXT iCOunt
         CASE %WM_DESTROY
            FOR iCount = 1 TO 3
               UnregisterHotKey CBHNDL, nAtom(iCount)
               GlobalDeleteAtom nAtom(iCount)
            NEXT iCount
         CASE %WM_HOTKEY
            SELECT CASE CBWPARAM
               CASE nAtom(1) 'Ctrl-a
                  AppActivate "Untitled - Notepad"  'switch to notepad window (if found)
                  WaitForNoKeys 'use this to wait for user to let go of keys (so our keys dont end up as ctrl keys)
                  sText = "{4 + 4 = 8} It is now " & DATE$ & " " & LEFT$(TIME$,5)
                  SendPlainText sText
               CASE nAtom(2) 'Ctrl-b
                  WaitForNoKeys  'use this to wait for user to let go of keys (so our keys dont end up as ctrl keys)
                  SendKeys "{AppActivate Untitled - Notepad}12{UP}34{END}567890" 'Switch to notepad then type 12 then go up and type 34 and go to end of line type 567890
                  SendKeys "{SLEEP 1000}{BACKSPACE}{SLEEP 500}" 'pause, backspace, pause
                  SendKeys "{BACKSPACE 3}"  'send 3 backspaces
               CASE nAtom(3) 'Ctrl-c
                  sText = INPUTBOX$("Enter string to send" + $CRLF + $CRLF + "You'll have 3 seconds " _
                           + "to switch back to the program to send keystokes.","Send what?")
                  SLEEP 3000
                  SendKeys sText
            END SELECT
      END SELECT
END FUNCTION
'=~=~=~=~=~=~=~=~=~=~=~=~=~=~=~=~=~=~=~=~=~=~=~=~=~=~=~=~=~=~=~=~=~=~=~
FUNCTION PBMAIN
   DIALOG NEW 0, "SendKeys example",,, 300, 30,%WS_MINIMIZEBOX OR %WS_SYSMENU OR %WS_CAPTION, 0 TO hDlg
   CONTROL ADD LABEL, hDlg, 205, "Switch to another program and then press Ctrl-A or Ctrl-B or Ctrl-C in to send keystrokes", 5, 10, 290, 15, %SS_CENTER
   DIALOG SHOW MODAL hDlg CALL DlgProc
END FUNCTION
'=~=~=~=~=~=~=~=~=~=~=~=~=~=~=~=~=~=~=~=~=~=~=~=~=~=~=~=~=~=~=~=~=~=~=~
'  other hot-key examples:
'RegisterHotKey CbHndl, nAtom, 0, Asc("D") ' D
'RegisterHotKey CbHndl, nAtom, 1, Asc("D") ' Alt-D
'RegisterHotKey CbHndl, nAtom, 2, Asc("D") ' Ctrl-D
'RegisterHotKey CbHndl, nAtom, 4, Asc("D") ' Shift-D
'RegisterHotKey CbHndl, nAtom, 1 + 2, Asc("D") ' Ctrl-Alt-D

------------------
"I haven't lost my mind... its backed up on tape... I think??"

[This message has been edited by William Burns (edited December 30, 2002).]

**Joseph Boccanera** · 15 Apr 2003, 12:55 PM

I am trying to send a CTRL END to a dialog Box so that I can go
to the end of TEXTBOX.

The Code Line is...
SendKeys "{^}{END}"

The Scroll bar elavator on the right side of the Window moves up and down.
but it never goes to the Bottom of the TextBox. Always goes back to the top.

I was able to use other sendkeys succesfully

Any Sugestions would be helpful..

------------------
mailto:[email protected][email protected]</A>

**Lance Edmonds** · 5 May 2003, 05:48 PM

Joseph: Use the %EM_SETSEL message.

Please note that the source code forum is intended for p[osting code only. Questions and discussions (and even thank you messages to show appreciation for source code, etc) should be posted in a more appropriate forum.

------------------
Lance
PowerBASIC Support
mailto:[email protected][email protected]</A>

**Guest** · 30 Aug 2003, 03:50 AM

A tiny mistake in "SUB SendPlainText(BYVAL sText AS STRING)" with %VK_SHIFT:

IF (iTempShifted AND 4) THEN KeyBd_Event %VK_MENU, MapVirtualKey(%VK_SHIFT, 0), 0, 0: SLEEP 0 'hold down alt

Better:
IF (iTempShifted AND 4) THEN KeyBd_Event %VK_MENU, MapVirtualKey %VK_MENU, 0), 0, 0: SLEEP 0 'hold down alt

Ok?

------------------

**Mike Trader** · 21 Feb 2005, 03:25 PM

A few notes from a not overly bright first time user...

Keep in mind that SendKeys is case sensitive

Code:

SendKeys "%f" ' ALT-f
SendKeys "%F" ' ALT-SHIFT-f

SendKeys "^f" ' CTRL-F
SendKeys "^f" ' CTRL-SHIFT-F

Sending Function keys like F9. 
SendKeys "{F9}"  ' Function Key F9
SendKeys "^{F9}" ' Ctrl-F9

SendKeys "{ENTER}" ' Enter see the sendkeys.inc file
SendKeys "{ESC}    ' Escape
SendKeys "{TAB}"   ' Tab      


To REGISTER other HotKeys with windows ....   
RegisterHotKey CbHndl, nAtom, 0, Asc("D") ' D                    
RegisterHotKey CbHndl, nAtom, 0, 68       ' D
RegisterHotKey CbHndl, nAtom, 1, Asc("D") ' Alt-D
RegisterHotKey CbHndl, nAtom, 2, Asc("D") ' Ctrl-D
RegisterHotKey CbHndl, nAtom, 4, Asc("D") ' Shift-D
RegisterHotKey CbHndl, nAtom, 1 + 2, Asc("D") ' Ctrl-Alt-D 

RegisterHotKey CbHndl, nAtom, 0, 13       ' ENTER - dangerous

RegisterHotKey CbHndl, nAtom, 0, ??? ' F9

      
Also, don't forget to process dialog events

      FOR i = 1 TO 40  ' Erase suggested text entry in target app
        DIALOG DOEVENTS
        SendKeys "{BACKSPACE}" 
      NEXT
      SendPlainText Addrs(i).Street ' Insert my entry
      
If you need to wait while the app you are sending keys to is processing use
      SendKeys "{SLEEP 3000}" \
      

I found that I could use the GetDesktopWindow()
function to look for windows that shoudl appear when commands are issued
or buttons hit. I also used it in a loop with a SLEEP to wait for a process
to complete knowing that the process puts up a window called
"Finding..." for example. I also want to use CTRL-C to copy the contents
of a textbox to clipboard and then examine it to see if it contains
results I am expecting.


If the developers of the target app were nice enought to throw up a dialog while processing (might not allways have time to be drawn)
then look for it. In my case the processing window was called "Finding..."

      WHILE Finding  ' wait for dialog to complete 
        DIALOG DOEVENTS 
        SendKeys "{SLEEP 4000}" 
      WEND    
where:

'¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤
 FUNCTION GetChildText(Ihwnd AS LONG) AS STRING   
  DIM Textlen AS LONG
  DIM sTemp AS STRING

    ON ERROR RESUME NEXT
    Textlen = SendMessage(Ihwnd, %WM_GETTEXTLENGTH, 0, 0)
    IF Textlen = 0 THEN
        FUNCTION = ""
        EXIT FUNCTION
    END IF
    Textlen = Textlen + 1
    sTemp   = STRING$(Textlen,0)
    Textlen = SendMessage(Ihwnd, %WM_GETTEXT, Textlen, STRPTR(sTemp))
    FUNCTION = LEFT$(sTemp, Textlen)
END FUNCTION

'¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤ 
FUNCTION Finding() AS LONG 

  DIM hWndChild AS LONG   
  DIM xRes AS STRING  
  DIM hWndParent AS LONG  
           
    hWndParent = GetDesktopWindow()
    hWndChild  = GetWindow(hWndParent, %GW_CHILD OR %GW_HWNDFIRST)
    DO WHILE hWndChild <> 0
      xRes = GetChildText(hWndChild)
      IF xRes <> "" THEN ' PRINT #hDbg, LEFT$(xRes, 80) 
        IF INSTR( xRes, "Finding..." ) THEN
          FUNCTION = 1 ' window is found
          EXIT FUNCTION
        END IF     
      END IF
      hWndChild = GetWindow(hWndChild, %GW_HWNDNEXT)
    LOOP  

END FUNCTION 
'¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤ 


similarly, if dont want to be stuck with untitled file ...
sAppDocName = FindFileName() ' to be clear
SendKeys "{AppActivate " + sAppDocName + "}" ' Use open file name 
SendKeys "^f"     ' CTRL-F ' open the Find Address window


where:
'¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤ 
FUNCTION FindFileName() AS STRING ' find doc open in MapSource

  DIM hWndChild AS LONG   
  DIM xRes AS STRING  
  DIM hWndParent AS LONG  

    hWndParent = GetDesktopWindow()
    hWndChild = GetWindow(hWndParent, %GW_CHILD OR %GW_HWNDFIRST)
    DO WHILE hWndChild <> 0
      xRes = GetChildText(hWndChild)
      IF xRes <> "" THEN ' PRINT #hDbg, LEFT$(xRes, 80) 
        IF INSTR( xRes, "- MapSource" ) THEN
          FUNCTION = TRIM$( xRes ) 
          EXIT FUNCTION
        END IF     
      END IF
      hWndChild = GetWindow(hWndChild, %GW_HWNDNEXT)
    LOOP  

    MSGBOX "MapSource Not Found",64,"Error" ' quit the app

END FUNCTION    

'¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤

------------------
Kind Regards
Mike

**John Montenigro** · 2 Sep 2015, 12:35 PM

SendKeys has been superseded, but IF you are still using it and IF you need to send a mouseclick to a foreign app to UNSELCT what was selected, here's a small mod:

In the SUB SendEachKey(), insert these 3 lines into the main CASE:

Code:

      case "{XMOUSECLICK}"              ' mouseclick to unselect text
         CALL MouseClick(UCASE$(MID$(sChar,2,1)),0,0)
         EXIT SUB

I stuck it right before "{LMOUSECLICK}".

-John

**John Montenigro** · 2 Sep 2015, 12:50 PM

Another tidbit for SendKeys...

IF you need the other app to save a file, AND IF that location is across a LAN, you may hit timing delays, so you add something like a {SLEEP 500}, and probably, you're fine; the app finally resolves the path, and your command to save then executes.

BUT: IF you're trying to feed a full path and filename to that app in one string, you may hit another problem - the other app gets lost and confused.
So if {SLEEP xxx} didn't help, try this: break the path and filename into two separate commands.

Change this:

Code:

SendKeys "P:\01 New\MyFile.txt{ENTER}"

Into:

Code:

SendKeys "P:\01 New\{ENTER}"   ' Step 1: first, force the change of directory

Sleep 200         'take a quick breather

SendKeys "MyFile.txt{ENTER}"   ' Step2: now provide the filename

-John

Announcement

Forum Guidelines

SendKeys PowerBasic replacement

SendKeys PowerBasic replacement

Comment

Comment

Comment

Comment

Comment

Comment

Comment